Get the path for a file in OS X with an AppleScript

08 May 2010

I frequently need to type in references to file locations. In OS X if I Get Info on a file or folder I can get a path, but I decided to write a script to widen my options and make things a little faster.

The script allows me to choose whether to get the path as a Mac path (: based) or a Posix path (\ based). It automatically copies it to the clipboard and gives me a notification. The notification in this case is just a dialog box, but if you use Growl, you could change this to register and display an appropriate notification.

The script will pick out any selected files or folders in Finder and copy & display them in the specified format.

try
    -- The user gets to choose which type of file path to return (default is Posix)
    set mode to (choose from list {"Mac", "Posix"} with title "File Path Type" with prompt "Choose the type of file path to retrieve:" default items {"Posix"}) as text
    
    --If the user doesn't cancel then get the path
    if mode is not equal to "false" then
        
        --Get the paths of all selected files
        set strFilePath to {}
        tell application "Finder"
            repeat with objItem in (get selection)
                if mode = "Posix" then
                    set end of strFilePath to POSIX path of (objItem as text)
                else
                    set end of strFilePath to objItem as text
                end if
            end repeat
        end tell
        
        --Copy the file paths to the clipboard
        set {strDelimeter, text item delimiters} to {text item delimiters, return}
        set the clipboard to strFilePath as text
        set text item delimiters to strDelimeter
        
        --Display a dialog for a couple of seconds that lists the file paths
        display dialog strFilePath as text with title "Path(s) copied to clipboard" with icon note giving up after 2 buttons {"Close"} default button "Close"
    end if
end try

Related posts that you may also like to read

Automation Documentation: Hooking SnippetsLab

26 Nov 2022

My efforts to link together my documentation and automation took a little jump forward recently with a new beta of the code library utility called SnippetsLab. A small update to the user interface has enabled me to construct a basic integration with Hookmark (the app formerly known as Hook). In this post I am going to explain a bit more about this.

Automation Documentation: Hooking Apple Shortcuts

01 Jun 2022

Earlier this week I wrote about how I was using Hook and Obsidian to support my documentation of automations. In this post I will aim to explain how I am using this set up to help me access documentation for my Apple Shortcuts automations.

Automation Documentation: Hooking Keyboard Maestro

31 May 2022

In my post yesterday, I described how I was using Obsidian and Hook to help me support my documentation of automations. Today, I am going to share something that helps me work with documenting Keyboard Maestro macros.

Automation Documentation: Hooking Automations with Obsidian

30 May 2022

For anyone who follows me on this blog or anywhere else, you are probably familiar with the fact that I enjoy automating things. Having my devices do things for me. This has numerous benefits including saving me time and effort in the future, reducing the opportunity for human error, teaching me new skills, etc. But the fact is, when you start building up a large toolbox of automations it can be hard to keep track of the details. Some automations lend themselves to inline documentation, but what if you want to do something more?

In this post I am going to describe some of my set up around documenting automations using two tools on the Mac - Hook and Obsidian.

ThoughtAsylum