Processing a Folder of Files

Option Explicit

Dim strFolder, strRootFolder, strBaseCommand

'Get the information and process it
strRootFolder = SelectFolder("Select folder containing files to be processed:")
strBaseCommand = InputBox("Enter the command line to run against all files." & vbCrLf & "Place a percentage symbol (%) where the filename will be substituted")
ProcessFolder strRootFolder

'------------
'SUB ROUTINES
'------------

'Identify each file in a folder and run the specified command against it.
Sub ProcessFolder(pstrFolder)
Dim objCurrentFolder, objFile
Dim colFilesInFolder
Dim strCommand
Dim objWSHShell, objFSO

'Initialise
Set objWshShell = Wscript.CreateObject("Wscript.Shell")
Set objFSO = Wscript.CreateObject("Scripting.FileSystemObject")
Set objCurrentFolder = objFSO.GetFolder(pstrFolder)
Set colFilesInFolder = objCurrentFolder.Files

For Each objFile in colFilesInFolder
strCommand = Replace(strBaseCommand,"%","""" & objFile.Path & """")
objWSHShell.Run strCommand
Next
End Sub

'---------
'FUNCTIONS
'---------

Function SelectFolder(pstrDialogLabel)
'Select a folder
Const BIF_returnonlyfsdirs = &H0001
Const BIF_editbox = &H0010

Dim objBrowseFolderDialog, objFolder, objFSO, objSelection
Dim bBrowseForFolder

Set objBrowseFolderDialog = WScript.CreateObject("Shell.Application")

bBrowseForFolder = true

While bBrowseForFolder
Set objFolder = objBrowseFolderDialog.BrowseForFolder (&H0, pstrDialogLabel, BIF_editbox + BIF_returnonlyfsdirs)

'Check that something has been returned
If IsValidFolder(objFolder) Then
Set objFSO = CreateObject("Scripting.FileSystemObject")

Set objSelection = objFolder.Self
If objFSO.FolderExists(objSelection.Path) Then
'A valid folder has been selected
SelectFolder = objSelection.Path
bBrowseForFolder = false
Else
'The selection is not a valid folder, try again...
MsgBox objFolder.Title & " is not a valid folder, please select another folder" _
, vbOKOnly & vbExclamation, "Invalid Selection"
End If
Else
'Nothing was selected, so return a null string
SelectFolder = ""
bBrowseForFolder = false
End If
Wend
End Function

Function IsValidFolder(pobjFolder)
'Check that we have a valid value
'i.e. you can concatenate it to a string
Dim strTest

On Error Resume Next

strTest = " " & pobjFolder

If Err <> 0 Then
IsValidFolder = false
Else
IsValidFolder = true
End If

On Error GoTo 0
End Function

Buy me a coffee

Related posts that you may also like to read

• 

  VBScript: Flip Line Endings

  28 Jun 2015

  Recently I was working for a client who had particularly strict controls around access and tools that I could use. Whilst the bulk of the work I was carrying out on their Linux box could be managed using vi, I found it a little limiting when analysing some of the log files the work was producing. On the Windows machine I was using to access the files I only had Windows notepad and this really doesn’t handle Linux file endings well. As a result I put together a quick VBScript to help with this.

  Read More
• 

  A Self Installing VBScript

  28 Feb 2014

  Over the years I’ve been doing technical support I’ve had quite a few useful VBS scripts that I’d copy over to a user’s machine. Then if it necessary, they could be run again at a later date (by remote control or referring the user to it’s location and get them to run it). However I quickly tired of manually doing this and dealing with the instances where I’d accidentally copied the script to the user’s desktop instead of the location I’d really wanted. As a result I created some extra lines to add into these scripts that would install the script to the desired location and then run it from there. This meant I could run it from a flash or network drive and it would automatically go to the right place - even updating older scripts.

  Read More
• 

  Random Files Generator

  26 Aug 2013

  Whilst doing some house keeping on some old VBScript files the other day I came across one for creating test files. I’ve blogged previously about creating test files using my MTF utility and whilst it or fsutil can be very useful, this script filled a particular niche. It was created as part of a test suite of scripts it creates multiple files of a specific size filled with random printable content.

  Read More
• 

  VBScript to Convert Microsoft Office Files (Word, Excel, PowerPoint) to PDF

  20 Dec 2012

  I spend a lot of my time working with Word documents and Excel spreadsheets - it’s in the nature of what I do. I frequently found that I need to create PDF copies of these files (to send out to clients) and eventually I grew tired of having to open the files one by one and select to save each as a PDF. As a result I created a bit of VBScript to automatically convert files for me (in Windows).

  Read More